run("Blobs (25K)");
run("Blobs (25K)");
run("Translate...", "x=10 y=0 interpolation=None");
run("Blobs (25K)");
run("Translate...", "x=20 y=0 interpolation=None");
run("Blobs (25K)");
run("Translate...", "x=30 y=0 interpolation=None");
run("Blobs (25K)");
run("Translate...", "x=40 y=0 interpolation=None");
run("Images to Stack", "name=Stack title= use");

makeRectangle(28, 18, 49, 57);
roiManager("Add");
makeRectangle(126, 21, 47, 68);
roiManager("Add");
makeRectangle(26, 114, 52, 54);
roiManager("Add");
makeRectangle(129, 119, 56, 59);
roiManager("Add");
makeRectangle(167, 190, 53, 39);
roiManager("Add");

roiManager("show all with labels")

imageName = getTitle();
run("Clear Results");
size = 0;
for(k = 0; k != roiManager("count"); k++)
{
	selectWindow(imageName);
	run("Select None");
	roiManager("deselect");
	roiManager("select", k);
	List.setMeasurements;
	print("x_center " + List.getValue("X") + " y_center " + List.getValue("Y") + " radius " + 0.5 * List.getValue("Width"));
	run("Radial Profile Angle", "x_center=" + List.getValue("X") + " y_center=" + List.getValue("Y") + " radius=" + 0.5 * List.getValue("Width") + " starting_angle=" + 0 + " integration_angle=" + 180 + " calculate_radial_profile_on_stack");

	for(j = 0; j != Ext.getStackSize; j++)
	{           
		for(i = 0; i != Ext.getBinSize; i++)
		{
			setResult("Roi"  , size + j * parseInt(Ext.getBinSize) + i, k);
			setResult("Slice", size + j * parseInt(Ext.getBinSize) + i, j + 1);
			setResult("X"    , size + j * parseInt(Ext.getBinSize) + i, parseInt(Ext.getXValue(i)));
			setResult("Y"    , size + j * parseInt(Ext.getBinSize) + i, parseInt(Ext.getYValue(j, i)));
		}
	}
	size += parseInt(Ext.getBinSize) * parseInt(Ext.getStackSize);
	updateResults();
}